Directory of image this file is from
This file as a plain text file

*20
	/// DISPLOT1
/
/DISPLOT
/
/AGRIPPA-ORD CORP.
/COPYRIGHT 1969
/ALL RIGHTS RESERVED
/
/SIGSYS TAPE BLOCKS
/10-13
/
	ION=6001
	IOF=6002
	PENUP=0
	PENDWN=1
	PENRT=5
	PENLFT=6
	PAPLFT=10
	PAPRT=7
	LFTRT=4
	LFTLFT=11
	RTRT=2
	RTLFT=3
	*20
	JMP PLOT
/
/DISPLAY
/
/USE BETA 1,2,3,4,5,6
	STC DPOINT
	ROR I 1
	STC CWORD
	QAC
	STC DBFLD
/
DNEXTB,	IOB
	IOF
	SET I 17
	DB0-1
DBFLD,	0
	LDA I
DPOINT,	0
	JMP OPGET
	JMP DEXT
	STC DPOINT
/
/DISPLAY A BUFFER
/
	ADD DB4
	BCL I
	7740
	BSE I
	LDF
	STA
	DTUMB
	STC GGET
	ADD DB5
	BSE I
	2000
	STC 2 	/PICKUP
	ADD DB0
	APO
	JMP DGRAPH
/
/TEXT
/
DTUMB,	LDF
/X FOR LINE
	LDA
	DB2
	ADD CWORD
	STC 1
/
/NEXT CHARACTER
DSNOW,	LDH 2
	SHD I
	3400
	JMP DNEXTB
	SHD I
	4500
	JMP DSN
	SHD I
	4300
	JMP DSCRLF
	SHD I
	7400
	JMP DSH
	SHD I
	7600
	JMP DSF
/
	ROL 1
	ADA I
	DSTABL
	STC 3
	ADD DB3 	/Y
	DSC 3
	DSC I 3
	DSC I
	0
DSN,	LDH I 2
	JMP DSNOW
/
/
DSCRLF,	JMP YBMP
	NOP
	LDH I 2
	JMP DTUMB
/
YBMP,	LDA I
	-17
	ADD DB3
	BCL I
	17
	STC DB3
	JMP 0
/
DSF,	LDA I
	JMP YBMP
	STC DSCRLF+1
	ADD DB3
	BCL I
	37
	STC DB3
	SFA
	BSE I
	200
DS,	ESF
	JMP DSN
/
DSH,	LDA I
	NOP
	STC DSCRLF+1
	SFA
	BCL I
	200
	JMP DS
/
/
/GRAPH DISPLAY
/
/
DGRAPH,	ADD DB1
	AZE I
	JMP LINE
	ROL 13
	SCR 14
	STC 1 	/HIST SWITCH
/
	ADD DB6 	/SIZE
	COM
	STC 3
	ADD DB10 	/SCALE
	APO
	JMP .+6
	BCL I
	7760
	BSE I
	ROL
	JMP .+6
	COM
	BCL I
	7760
	BSE I
	SCR
	STC DSCAL
	ADD DB2
	STC 4 	/XPOS
	SET I 6
ONE,	1 	/POINT POSITION
/
/
GGET,	LDF
	LDA 2
	STA I
YVAL,	0
DSCAL,	SCR
	ADD DB3 	/YPOS
	STA I
DOT,	0
	DIS 4
	XSK 1
	SKP
	JMP DOBAR
DG1,	LDA
	6
	SAE
	DB7
	SKP
	JMP DOCURS
DG2,	LDA
	DB11 	/DATSPAC
	ADD 2
	STC 2
	ADD DB12
	ADD 4
	STC 4
	XSK I 6
	XSK I 3
	JMP GGET
	JMP DNEXTB
/
/
DOBAR,	COM
	ADD DB3 	/Y
	SCR 2
	AZE I
	JMP DG1
	APO
	JMP UPGO
	COM
	STC 5
	ADD DB3 	/Y
	ADD MFOUR
	DIS 4
	XSK I 5
	JMP .-3
	JMP DG1
/
UPGO,	STC 5
	ADD DB3 	/Y
	ADD FOUR
	DIS 4
	XSK I 5
	JMP .-3
	JMP DG1
/
DOCURS,	LDA
	DPOINT
	ADD MTWO
	STC .+6
	ADD DBFLD
	STC .+1
	LDF
	ADD YVAL
	STA
	0
/
	LDA I
MONE,	-1
	STC .+13
	ADD DOT
	COM
	ADD DB3
	APO
	JMP CUP
	SET I 5
	-20
	LDA
	DOT
	ADA I
	1
	DIS 4
	XSK I 5
	JMP .-4
	JMP DG2
CUP,	LDA
	ONE
	STC .-7
	JMP .-15
/
/
/LINES OR AXIS
/
/
LINE,	LDA
	DB3
	SAE
	DB5
	SKP
	JMP DOH
	LDA
	DB2
	SAE
	DB4
	JMP DNEXTB 	/NOT SQUARE LINES
/
/VERTICAL
/
DOV,	STC 4
	ADD DB3
	DIS 4
	SAE
	DB5
	SKP
	JMP DNEXTB
	ADD ONE
	JMP .-6
/
DOH,	SET 4
	DB2
	LDA
	DB3
	DIS 4
	LDA
	4
	SAE
	DB4
	SKP
	JMP DNEXTB
	ADD ONE
	STC 4
	JMP .-13
/
/EXIT TO HANDLER
/
DEXT,	LIF 3
	JMP 1777
	EJECT
DSTABL,	0101
	0101
	4477 	/1.A
	7744
	5177 	/2.B
	2651
	4136 	/3.C
	2241
	4177 	/4.D
	3641
	4577 	/5.E
	4145
	4477 	/6.F
	4044
	4136 	/7.G
	2645
	1077 	/10.H
	7710
	7741 	/11.I
	0041
	4142 	/12.J
	4076
	1077 	/13.K
	4324
	0177 	/14.L
	0301
	3077 	/15.M
	7730
	3077 	/16.N
	7706
	4177 	/17.O
	7741
	4477 	/20.P
	3044
	4276 	/21.Q
	0376 
	4477 	/22.R
	3146
	5121 	/23.S
	4651
	4040 	/24.T
	4077
	0177 	/25.U
	7701
	0176 	/26.V
	7402
	0677 	/27.W
	7701
	1463 	/30.X
	6314
	0770 	/31.Y
	7007
	4543 	/32.Z
	6151
	4177 	/33.\
	0000
	0000 	/34.NOTHING
	0000
	0000 	/35.]
	7741
CWORD,	0
SPC,	0
FOUR,	4
MTWO,	-2
	0000 	/40.SPACE
	0000
	7500 	/41.EXCLAMATION
	0000
	7000 	/42."
	0070
	0
	0
	0
	0
	0
	0
	5166 	/46.I
	0526
	0000 	/47.TAB
	0000
	3600 	/50.LEFT PARENTHESIS
	0041
	4100 	/51.RIGHT PARENTHESIIS
	0036
	2050 	/52.ASTERISK
	0050
	0404 	/53.+
	0437
	0500 	/54.,
	0006
	0404 	/55.-
	0404
	0001 	/56..
	0000
	0601 	/57.OPPOSITE\
	4030
	4536 	/60.0
	3651
	2101 	/61.1
	0177
	4523 	/62.2
	2151
	4122 	/63.3
	2651
	2414 	/64.4
	0477
	5172 	/65.5
	0651
	1506 	/66.6
	4225
	4443 	/67.7
	6050
	5126 	/70.8
	2651
	5122 	/71.9
	3651
	2200 	/72.COLON
	0000
	4601 	/73.SEMICOLON
	0000
M10,	-10 	/74. NULL
C1000,	1000
	1212 	/75.=
	1212
	0000 	/76. NULL
	0000
	4020 	/77.QUESTION  MARK
	2055
/
	EJECT
/
/BUFFERS AND OPERAND GETTER
/
/USE BETA 14,15,16,17
DB0,	0
DB1,	0
DB2,	0
DB3,	0
DB4,	0
DB5,	0
DB6,	0
DB7,	0
DB10,	0
DB11,	0
DB12,	0
DB13,	0
/
OPGET,	STC 16
	SET 15
	0
	SET I 14
	-15
ONX,	LDA 16
	SAE I
	4002
	SKP
	JMP SPIN
	SAE I
	4000
	SKP
	JMP SOX
	SAE I
	4001
	SKP
	JMP LOX
	XSK I 14
	SKP
	JMP SOX
	STA I 17
	XSK I 16
	JMP ONX
/
LOX,	XSK I 15
SOX,	XSK I 16
	NOP
	LDA
	15
	STC PX
	ADD 16
	IOB
	ION
PX,	JMP
/
SPIN,	LDA I 16
	SAE I
	4001
	JMP .-3
	LDA I 16
	JMP ONX
/
PB0,	0
PB1,	0
PB2,	0
PB3,	0
PB4,	0
PB5,	0
PB6,	0
PB7,	0
PB10,	0
PB11,	0
PB12,	0
PB13,	0
	EJECT
/
/PLOTTER ROUTINES
/
/USE BETA 7,10,11,12,13
PLOT,	STC PPOINT
	QAC
	STC PBFLD
PNEXTB,	IOB
	IOF
	SET I 17
	PB0-1
PBFLD,	LDF
	LDA I
PPOINT,	0
	JMP OPGET
	JMP PEXT
	STC PPOINT
/
/PLOT A BUFFER
/
	ADD PB2
	JMP MUL2
	STC PB2
	ADD PB3
	JMP MUL2
	ADD C1000
	STC PB3
	ADD PB4
	BCL I
	7740
	BSE I
	LDF
	STA
	TUMB
	STC GUMB
	ADD PB5
	BSE I
	2000
	STC 7
	JMP SETPEN
/
	ADD PB0
	APO
	JMP PGRAPH
/
/TEXT
/
TUMB,	LDF
/
PSNOW,	LDH 7
	SHD I
	3400
	JMP PNEXTB
	SHD I
	4500
	JMP PSN
	SHD I
	4300
	JMP PSCRLF
	SHD I
	7400
	JMP PSH
	SHD I
	7600
	JMP PSF
/
	ROL 1
	ADA I
	TABLA-3
	STC 10 	/BIT POINTER
/
/PLOT A SINGLE CHARACTER
/
/
	STC XSUM
	STC YSUM
	SET I 11
	TABLB-1
C,	LDA I 10
	STC ROTAT
	LDA I 11
	SCR 6
	JMP CSCAL
	STC MOVMNT
	LDA 11
	ROL 6
	SCR 6
	JMP CSCAL
	STC MOVMNT+1
	SRO I
ROTAT,	0
	JMP CLIN 	/PLOT LINE
/
/SUM LINE
/
	ADD MOVMNT
	ADD XSUM
	STC XSUM
	ADD MOVMNT+1
	ADD YSUM
	STC YSUM
/
DE,	SRO I
	3777
	JMP C+2
	SRO I
	2525
	JMP C 	/NEXT BIT LIST
/LAST MOVEMENT
	LDA
	XSUM
	ADD PNX
	AZE I
	CLR
	STC PNX
	ADD YSUM
	ADD PNY
	AZE I
	CLR
	STC PNY
	JMP MOVUP
/
	JMP PSN 	/NEXT CHARACTER
/
/
CLIN,	LDA
	XSUM
	ADD PNX
	AZE I
	CLR
	STC PNX
	ADD YSUM
	ADD PNY
	AZE I
	CLR
	STC PNY
	JMP MOVUP
/
	LDA
	MOVMNT
	ADD PNX
	AZE I
	CLR
	STC PNX
	ADD MOVMNT+1
	ADD PNY
	AZE I
	CLR
	STC PNY
	STC XSUM
	STC YSUM
	JMP MOVDWN
	JMP DE
/
/
/PLOT CHARACTER TABLES
/
/
TABLA,	1474 	/A
	3000
	0376 	/B
	1100
	0374 	/C
	0000
	0170 	/D
	0006
	0374 	/E
	1000
	0074 	/F
	1000
	0774 	/G
	2000
	1460 	/H
	3000
	0000 	/I
	0030
	1701 	/J
	0000
	0062 	/K
	1100
	0360 	/L
	0000
	1462 	/M
	0200
	1460 	/N
	0300
	1774 	/O
	0000
	1074 	/P
	3000
	1774 	/Q
	0100
	1074 	/R
	3100
	0734 	/S
	3000
	0014 	/T
	0030
	1760 	/U
	0000
	1020 	/V
	0003
	1461 	/W
	0100
	0003 	/X
	0300
	0002 	/Y
	0220 
	0317 	/Z
	0000
/
	0374 	//
	0000
	0000 	/BACKSLASH
	0300
	1714 	/BACK/
	0000
	0000 	/NULL
	0000 
M20,	-20 	/NULL
C40,	40
	0000 	/SPACE
	0000
	0000 	/EXCLAMATION
	0010
	0020 	/QUOTE
	0010
	0000 	/LF
	0000
XSUM,	0 	/NULL
YSUM,	0 	/NULL
MOVMNT,	0 	/CR
	0
	4010 	/AMPERSAND
	0303
	0000 	/TAB
	0000
	4000 	/L PAREN
	0001
	0000 	/R PAREN
	0006
	4000 	/ASTERISK
	3037
	0000 	/+
	3030
	0000 	/,
	0002
	0000 	/-
	3000
	0600 	/.
	2020
	0003 	/\
	0000
/
	0170 	/0
	0030
	0000 	/1
	0030
	0150 	/2
	1010
	0110 	/3
	1030
	4000 	/4
	1030
	0130 	/5
	1020
	0160 	/6
	1020
	0010 	/7
	0030
	0170 	/8
	1030
	0030 	/9
	1030
	0000 	/COLON
	0000
	0001 	/SEMICO
	0010
CSCAL,	SCR 1 	/NULL
	JMP 0
	0300 	/=
	3000
MFOUR,	-4 	/NULL
M4000,	-4000
	1014 	/?
	2020
/
/STANDARD MOVEMENT TABLE
/
TABLB,	1014
	1014
	6700
	6700
	0063
	0063
	1000
	1000
	0014
	0014
	6700
	6763
	1063
	1014
	6714
	0063
	0063
	1000
	6714
	6714
	0063
	1000
	1000
	1063
/
/
	EJECT
PSCRLF,	JMP PYBMP
	NOP
	JMP SETPEN
PSN,	LDH I 7
	JMP PSNOW
/
SETPEN,	SET 12
	0
	LDA
	PB2
	STC PNX
	ADD PB3
	STC PNY
	JMP MOVUP
	JMP 12
/
PYBMP,	LDA I
	-17
	ADD PB3
	BCL I
	17
	STC PB3
	JMP 0
/
PSF,	LDA I
	JMP PYBMP
	STC PSCRLF+1
	ADD PB3
	BCL I
	77
	STC PB3
	LDA I
	NOP
	STC CSCAL
	JMP PSN
/
PSH,	LDA I
	NOP
	STC PSCRLF+1
	LDA I
	SCR 1
	STC CSCAL
	JMP PSN
/
PEXT,	LDA I
	2000
	STC PNX
	STC PNY
	JMP MOVUP
	STC PNX
	STC PNY
	STC POX
	STC POY
	LIF 3
	JMP 1776
	EJECT
/
/GRAPH
/
PGRAPH,	ADD PB1 	/TYPE
	AZE I
	JMP PLINE
	ROL 13
	SCR 14
	STC 11 	/HIST SWITCH
	STC PDOT 	/PLOT POINT
/
GUMB,	LDF
/
	ADD PB6
	COM
	STC 13 	/BUFSIZ
	ADD PB6
	ADA I
	-600
	COM
	SCR 13
	STC DOUB
	ADD PB10 	/SCALE
	ADA I
	1
	APO
	JMP .+6
	BCL I
	7760
	BSE I
	ROL
	JMP .+6
	COM
	BCL I
	7760
	BSE I
	SCR
	STA
	PSCAL1
	STC PSCAL
/
PGET,	LDA 7
PSCAL,	SCR
	ADD PB3
	STC PNY
	JMP MOVUP
/
PGET1,	LDA 7
PSCAL1,	SCR
	ADD PB3
	STC PNY
	JMP MOVDWN
/
PG1,	LDA I
	1
	ADM I
PDOT,	0
	SAE
	PB7
	JMP PG2
/CURSOR OUT
	LDA I
	40
	ADD POY
	STC PNY
	LDA I
	2
	ADD POX
	STC PNX
	JMP MOVDWN
	LDA I
	-40
	ADD POY
	STC PNY
	LDA I
	-2
	ADD POX
	STC PNX
	JMP MOVDWN
/
PG2,	CLR
	XSK 11
	JMP .+4
	ADD PB3
	STC PNY
	JMP MOVDWN
/
	ADD PB11
	ADD 7
	STC 7 	/DATSPAC
	LDA I
DOUB,	0
	SCR I 1
	ADD PB12
	LZE I
	ROL 1
	ADD PNX
	STC PNX
	XSK I 13
	SKP
	JMP PNEXTB
	XSK 11
	JMP PGET1
	JMP PGET
	EJECT
/
/LINE OR AXIS
/
PLINE,	LDA
	PB4
	JMP MUL2
	STC PNX
	ADD PB5
	JMP MUL2
	ADD C1000
	STC PNY
	JMP MOVDWN
/
	JMP PNEXTB
/
/
MOVDWN,	LDA I
	1
	SKP
MOVUP,	CLR
	STC NPEN
	ADD 0
	STC MVX
/
	LDA
	POX
	SAE
	PNX
	JMP DOPEN
	LDA
	POY
	SAE 
	PNY
	JMP DOPEN
	JMP MVX-1
/
DOPEN,	LDA
	PNY
	APO
	JMP .+4
	BCL I
	6000
	JMP .+3
	BSE I
	6000
	STC PNY
	IOB 4
NPEN,	0
/
	IOB 1
	25
	MVP
	JMP .-3
	IOB 5
/
/
MVP,	CLR
MVX,	JMP
/
MUL2,	MUL I
	2
	JMP 0
	EJECT
/PLOT LINE DRIVER
	PRET=1777
	PLTXM=1770
	*1627
	PMODE
MOVX,	LINC
	LMODE
	LIF 0
	JMP PRET
PLOTX,	PDP
	PMODE
	TAD POX
	CIA CLL
	TAD PNX
	SNL
	CIA
	DCA PLOTDX
	RAL
	DCA PLOTMV
	TAD PNX
	DCA POX
	TAD POY
	CIA CLL
	TAD PNY
	SNL
	CIA
	DCA PLOTDY
	TAD PLOTMV
	RAL
	DCA PLOTMV
	TAD PNY
	DCA POY
	TAD PLOTDX
	CIA CLL
	TAD PLOTDY
	SNL CLA
	JMP PLOT2
	TAD PLOTDX
	DCA PLOTNA
	TAD PLOTDY
	DCA PLOTDX
	TAD PLOTNA
	DCA PLOTDY
	IAC
	AND PLOTMV
	TAD PLOTT1
	JMP .+4
PLOT2,	TAD PLOTMV
	CLL RAR
	TAD PLOTT2
	DCA PLOTNA
	TAD I PLOTNA
	DCA PLOT4+1
/
	TAD PLOTMV
	TAD PLOTT3
	DCA PLOTMV
	TAD I PLOTMV
	DCA PLOTDB+1
	TAD PLOTDX
	CLL RAR
	DCA PLOTNA
	TAD PLOTDX
	CMA
	DCA PLOTMV
PLOT3,	ISZ PLOTMV
	SKP
	JMP MOVX
	TAD PLOTNA
	TAD PLOTDY
	DCA PLOTNA
	TAD PLOTNA
	CMA CLL
	TAD PLOTDX
	SZL CLA
	JMP PLOT4-1
	LINC
	LMODE
PLOTDB,	LDA I
	0
	LIF 0
	JMP PLTXM
	PDP
	PMODE
	TAD PLOTDX
	CIA
	TAD PLOTNA
	DCA PLOTNA
	JMP PLOT3
/
	LINC
	LMODE
PLOT4,	LDA I
	0
	LIF 0
	JMP PLTXM
	PDP
	PMODE
	JMP PLOT3
/
PLOTT1,	.+1
	5 	/PEN RIGHT
	6 	/PEN LEFT
PLOTT2,	.+1
	7
	10
PLOTT3,	.+1
	2
	4
	3
	11
/
	LMODE
POX,	0
POY,	0
PNX,	0
PNY,	0
PLOTDX,	0
PLOTDY,	0
PLOTNA,	0
PLOTMV,	0
/
/DISPLOT1
/JUNE 73