/ INSPECTION DEFECT ROUTINES                	27-AUG-91
/
/
/
/	DDDD   EEEEE  FFFFF   222
/	D   D  E      F      2   2
/	D   D  E      F          2
/	D   D  EEEE   FFFF      2
/	D   D  E      F        2
/	D   D  E      F       2
/	DDDD   EEEEE  F      22222
/
/
/

/
/EDIT HISTORY:
/
/8-JUL-91	(LHN)		FOR VERSION 4A
/	1)  CHANGED CH2RES TO CH1SPL
/	2)  CHANGED DEF2 FOR SICK INSPECTOR
/
/27-JUL-91	(LHN)
/	1)  CHANGES INPUT BIT FOR SPLICE
/
/7-AUG-91	(LHN)
/	1)  CHANGED INTERLOCK CODE TO MSTINL
/
/
/27-AUG-91	(LHN)		FOR VERSION 4B
/	1)  DELETED INPUT DATA WORD - SICKD2
/


	TASK=	CH2DEF
	CUR=	DEF2FLD
	INIWT=	0
	VERS=	4

	TASK2=	CH1SPL
	CUR2=	DEF2FLD
	INIWT2=	0
	VERS2=	4



	FIELD DEF2FLD%10
	*DEF2LOC
/
/
/	DR8 INPUT REGISTER 54
/
/
/    BIT			SIGNAL
/
/     0		TOGGLE BIT
/     1		GOOD SHEET
/     2		REJECT SHEET
/     3		SHEET NOT INSPECTED
/     4		SPLICE
/     5		EMULSION FAULT
/
/     6
/     7
/     8
/     9
/    10
/    11
/
/
/
/
/
/	DR8 INPUT REGISTER 55
/
/
/    BIT			SIGNAL
/
/     0		INSPECTOR READY
/     1		INSPECTOR ACTIVE
/     2		ZONING ACTIVE
/     3		DANGER OF FOG
/     4		SICK SYSTEM ERROR
/     5		CHOP LENGTH ALARM
/	
/     6		REJECT ALARM
/     7		READY TO USE MIRROR PARAMETERS
/     8
/     9
/    10
/    11
/
/
/
/
/%RT	SHEET TYPE CODE BITS
/
/%TW	THE CODE BITS USED BY MAST FOR MARKING THE TYPE OF
/	SHEET BEFORE THE CHOP LINE ARE AS FOLLOWS:
/
/%TN	DATA		MEANING
/%TN	BIT
/%TN
/%TN	0		TRAY EJECT CONTROL
/%TN	1		SPLICE SAMPLE
/%TN	2		IN-ROLL SPLICE SAMPLE
/%TN
/%TN	3		"EXTRA" SAMPLE
/%TN	4		AUTOMATIC OR MANUAL REJECT
/%TN	5		BOX SAMPLE
/%TN
/%TN	6		START ROLL SAMPLE
/%TN	7		END ROLL SAMPLE
/%TN	8		SPLICE ON THIS SHEET
/%TN
/%TN	9		SHEET NOT INSPECTED
/%TN	10		SHEET HAS AN EMULSION MISS
/%TN	11		SHEET IS A REJECT
/%TN
/%TN
/
/
/
/
/
/	THE SHEET CODE BITS AFTER THE CHOP LINE ARE:
/
/
/	DATA		MEANING
/	BIT
/
/	0		EJECT TRAY AFTER THIS SHEET
/	1
/	2
/
/	3		SAMPLE MARK THIS SHEET
/	4
/	5
/
/	6		PUT SHEET IN SAMPLE TRAY
/	7		PUT SHEET IN REJECT A TRAY
/	8		PUT SHEET IN REJECT B TRAY
/
/	9		PUT SHEET IN PRODUCT C TRAY
/	10		PUT SHEET IN PRODUCT A TRAY
/	11		PUT SHEET IN PRODUCT B TRAY
/
/
/
/
/%RP	PROCESS SHEET DEFECT DATA FOR CHANNEL 2
/
/
/%TW	THIS ROUTINE IS CALLED  AS
/	EACH SHEET BOUNDRY (YET TO BE CHOPPED) CROSSES THE 
/	INSPECTION POINT FOR CHANNEL 2.  IF CHANNEL 2
/	IS ENABLED, THE DEFECT DATA FOR THIS SHEET AND
/	THE FAILURE FLAG FROM SELF CHECK ARE "OR"ED 
/	INTO THE DEFECT MEMORY TABLE AT THE CHANNEL 2
/	POSITION.  THIS DATA IS LATER USED BY "PRODCT"
/	TO DETERMINE THE QUALITY OF THIS SHEET.
/
START,	CAL
	SUSPND		/GO TO SLEEP 'TIL NEEDED.

	CLB
	TAD CH2LOC	/FORM ADDRESS POINTER INTO MEMORY
	TAD MEMPTR	/ TABLE AND SAVE THE CURRENT
	AND (0377)	/ LOCATION OF THE CHANNEL POINTER
	TAD (MEMTBL)	/ FOR THE RESOLUTION ROUTINE.
	DCA CH2PTR

	DBRI50		/IS MAST IN THE "TEST" MODE ?
	AND (0040)
	SZA CLA
	JMP DEF21	/NO, GO ON.
	DBRI52		/IS THIS CHANNEL DISABLED ?
	AND (0002)
	SZA CLA
	JMP DEF29	/YES, EXIT.

DEF21,	CLB MQL		/CLEAR THE MQ REGISTER
	DBRI54		/READ THE NEW SHEET DATA
	AND (1700)	/IS THIS A REJECT SHEET?
	SZA CLA
	JMP DEF22	/YES, GO ON
	DBRI54		/IS THE GOOD SHEET BIT?
	AND (2000)
	SZA CLA
	JMP DEF24	/YES, CHECK TOGGLE BIT
	JMP DEF26	/NO, DO ERROR
/
DEF22,	DBRI54		/DETERMINE TYPE OF DEFECT
	AND (0100)	/IS THE EMULSION FAULT BIT SET ?
	SNA 
	JMP DEF22A	/NO, GO ON
	DCA EMULFG	/YES, SAVE EMULSION FAULT BIT
			/ FOR DIGINP.
	AC0002		/SET EMULSION FAULT DEFECT BIT
	MQL

DEF22A,	DBRI54
	AND (0200)	/SPLICE DEFECT SEEN ?
	SNA CLA
	JMP DEF22B	/NO, GO NO
	TAD (10)	/YES, OR SPLICE BIT TO DEFECT
	MQA		/ DATA
	MQL

DEF22B,	DBRI54	
	AND (0400)	/WAS SHEET INSPECTED?
	SNA CLA
	JMP DEF22C	/NO, GO ON
	TAD (4)		/YES, OR IN NOT INSPECTED BIT
	MQA
	MQL

DEF22C,	DBRI54	
	AND (1000)	/WAS SHEET A REJECT ?
	SNA CLA
	JMP DEF23	/NO, GO ON
	AC0001		/YES, OR REJECT BIT INTO DEFECT
	MQA		/ DATA
	MQL

DEF23,	TAD I CH2PTR	/NOW 'OR' THE DEFECT DATA INTO
	MQA		/ THE MEMORY TABLE
	DCA I CH2PTR
/
/	CHECK INSPECTOR TOGGLE BIT
/
DEF24,	TAD FCHOPF	/IS THIS THE FIRST CHOP ?
	SZA CLA
	JMP DEF25	/YES, GO ON.
	DBRI54		/READ THE TOGGLE BIT
	AND (4000)
	TAD CH2TOG	/IS IT THE SAME AS LAST TIME?
	SNA CLA
	JMP DEF26	/YES, DO ERROR
DEF25,	DBRI54		/GET THE TOGGLE BIT AGAIN AND
	AND (4000)	/ SAVE IT FOR NEXT TIME.
	DCA CH2TOG
	JMP DEF29	/ALL DONE....
/
/	DO INSPECTOR ERROR
/
DEF26,	DBRI50		/IS MAST IN THE "TEST" MODE ?
	AND (0040)
	SNA CLA
	JMP DEF29	/YES, GO ON.

	CAL 		/NO, GO OPEN THE INSPECTOR
	SEND		/ INTERLOCK
	INLOCK
	CH2MSG

	TAD (4)		/SET SHEET DEFECT BIT
	MQL
	TAD I CH2PTR	/NOW 'OR' THE DEFECT DATA INTO
	MQA		/ THE MEMORY TABLE
	DCA I CH2PTR


DEF29,	DBRI54		/SAVE THE SICK INPUT DATA
	DCA SICKD1
	JMP START	/NOW WE ARE ALL DONE


CH2PTR,	0		/POINTER INTO THE DEFECT MEMORY
CH2TOG,	0		/LAST INSPECTOR TOGGLE BIT

CH2MSG,	ZBLOCK 3	/OPEN MAST INTERLOCK
	MSTINL+MOPM14	/SAY SELF CHECK ERROR FOR NOW
/

	PAGE
/
/
/%RP	CHANNEL 1 SPLICE ROUTINE
/
/
/
/
START2,	CAL
	SUSPND		/GO TO SLEEP 'TIL NEEDED.

	CLB
	TAD CH1LOC	/FORM ADDRESS POINTER INTO MEMORY
	TAD MEMPTR	/ TABLE AND SAVE THE CURRENT
	AND (0377)	/ LOCATION OF THE CHANNEL POINTER
	TAD (MEMTBL)	/ FOR THE RESOLUTION ROUTINE.
	DCA CH1PTR

	DBRI50		/IS MAST IN THE "TEST" MODE ?
	AND (0040)
	SZA CLA
	JMP DEF11	/NO, GO ON.
	DBRI52		/IS THIS CHANNEL DISABLED ?
	AND (0004)
	SZA CLA
	JMP START2	/YES, EXIT.

DEF11,	DBRI50		/READ AND CLEAR OUR DR8 BIT - IT
	AND (0010)	/ IS THE SPLICE BIT.
	DBCI50
	SNA CLA
	JMP DEF12
	TAD (0010)	/SET SPLICE BIT

	TAD I CH1PTR	/NOW 'OR' THE DEFECT DATA INTO
DEF12,	DCA I CH1PTR	/ THE MEMORY TABLE. THIS WILL ALSO
			/ CLEAR THE TABLE OF "OLD" DATA.
	TAD I CH1PTR	/LEAVE THE CHANNEL 2 DATA AROUND
	DCA SPLFLG	/ FOR "MISC1".
	JMP START2

CH1PTR,	0
	

	PAGE

	NOPUNCH		/FIELD 1 COMMON FOLLOWS
	XLIST 1