Directory of image this file is from
This file as a plain text file

/47
/
/
/%R	TURN THE STACKER GATES ON WHEN NEEDED
/
/%TW	THIS ROUTINE IS CALLED FROM "MEMWRK" DURING THE 
/	SERVICING OF A MOTION PULSE, AND MONITORS THE STACKER
/	GATE TURN ON DELAY TIMING.  THE TURN ON DELAY COUNTERS
/	ARE SET UP BY THE INDIVIDUAL GATE HANDLERS.  WHEN ONE
/	OF THESE DELAY COUNTERS GOES TO ZERO "GATEON" TURNS ON
/	THE GATE AND TRAY AIR VALVES FOR THAT STACKER POSITION.
/
/
GATEON,	0
	CLB		/HAS THE SAMPLE GATE TURN ON DELAY
	ISZ SMGTON	/TIMED OUT ?
	JMP .+3		/NO, GO ON
	TAD (4040)	/YES, TURN SAMPLE GATE AND TRAY AIR ON
	DBSO50
	CLB		/HAS THE REJECT A GATE TURN ON DELAY
	ISZ RAGTON	/TIMED OUT ?
	JMP .+3		/NO, GO ON
	TAD (2020)	/YES, TURN REJ. A GATE AND TRAY AIR ON
	DBSO50
	CLB		/HAS THE REJECT B GATE TURN ON DELAY
	ISZ RBGTON	/TIMED OUT ?
	JMP .+3		/NO, GO ON
	TAD (1010)	/YES, TURN REJ. B GATE AND TRAY AIR ON
	DBSO50
	CLB		/HAS THE PRODUCT A GATE TURN ON DELAY
	ISZ PAGTON	/TIMED OUT ?
	JMP .+3		/NO, GO ON
	TAD (0202)	/YES, TURN PROD. A GATE AND TRAY AIR ON
	DBSO50
	CLB		/HAS THE PRODUCT B GATE TURN ON DELAY
	ISZ PBGTON	/TIMED OUT ?
	JMP I GATEON	/NO, RETURN
	TAD (0101)	/YES, TURN PROD. B GATE AND TRAY AIR ON
	DBSO50
	CLB
	JMP I GATEON	/RETURN