Directory of image this file is from
This file as a plain text file

/48
/
/
/%R	ENTER THE MEMORY JUMP TABLE
/
/%TW	COME HERE FROM "MEMORY" OR "SROCTR" FOR EACH MOTION
/	INTERRUPT, SET UP TO ENTER THE JUMP TABLE AND DO
/	WHATEVER IS NEEDED FOR THIS MOTION PULSE.  SOME TASKS
/	NEED BE DONE ONLY ONCE PER SHEET LENGTH OF PRODUCT
/	TRAVEL, BUT IT IS IMPORTANT THAT THEY BE DONE WHEN 
/	THE SHEETS ARE IN CERTAIN SPECIFIED POSTIONS.
/	THESE FUNCTIONS INCLUDE SETTING UP THE STACKER GATE
/	DELAY COUNTERS, FIRING THE SAMPLE MARKER, AND STORING
/	THE INSPECTOR DEFECT DATA FOR A SHEET.
/
/%TD	A "JUMP TABLE" IS USED TO DIRECT THE PROGRAM TO THE
/	PROPER TASK SERVICE ROUTINE.  THE JUMP TABLE CONTAINS
/	ONE LOCATION FOR EACH INDIVIDUAL MOTION PULSE IN THE
/	CURRENT SHEET LENGTH.  EACH LOCATION CONTAINS THE 
/	ADDRESS OF A LIST OF SUBROUTINES TO BE EXECUTED FOR
/	THAT SPECIFIC MOTION PULSE.  THE SUBROUTINE LIST IS 
/	TERMINATED BY A RETURN TO "MEMWRK".  NOTE THAT IF 
/	THERE IS NO WORK TO BE DONE FOR A PARTICULAR MOTION
/	PULSE, AN IMMEDIATE RETURN TO "MEMWRK" IS PLACED IN
/	IT'S JUMP TABLE POSITION.  THE JUMP TABLE IS BUILT
/	WHEN THE PROGRAM IS FIRST STARTED AND AT END-OF-ROLL
/	SUMMARY TIME.  THIS TABLE MUST BE REBUILT WHEN THE
/	CHOP LENGTH CHANGES.
/
/%TD	"MEMWRK" ALSO MAINTAINS THE SHEET LENGTH COUNTER. A
/	CHECK IS MADE TO INSURE THAT THE SHEET LENGTH 
/	COUNTER DOES NOT EXCEED THE KNOWN SHEET LENGTH.  IF
/	IT DOES, THE CHOP PULSE IS MISSING (OR LATE) AND THE
/	MAST MONITOR INTERLOCK IS OPENED TO STOP THE MACHINE.
/	THE "CHOP SIGNAL MISSING" ERROR IS ALSO QUEUED FOR
/	THE CONSOLE TELETYPE.
/
/
MEMWRK,	0
	ISZ SHLCNT	/INCREMENT THE SHEET LENGTH COUNTER
	TAD SHLENG	/CHECK THAT THE SHEET LENGTH COUNTER
	CIA		/DOES NOT EXCEED THE SHEET LENGTH BY
	TAD SHLCNT	/MORE THAN 1 MOTION PULSE.
	SPA SNA
	JMP MEM1	/IT IS OK, GO ON
	CLL RAR		/THE SHEET LENGTH COUNTER EXCEEDS THE
	CLL RAR
	SNA CLA		/SHEET LENGTH. BY MORE THAN 3 ?
	JMP MEM1	/NO, GO ON
	ISZ FCHOPF
	TAD FCHOPF	/IS THIS THE FIRST CHOP AFTER STARTUP ?
	SZA CLA
	JMP MEM1-2	/YES, GO ON
/49
	CIF 30
	CLB STL RAR
	JMS I (TTYCUE)	/NO, CUE "CHOP SIGNAL MISSING" FOR
	TEXT09		/OUTPUT.
	CLB IAC
	DCA SHLCNT	/RESET THE SHEET LENGTH COUNTER

MEM1,	JMS GATEON	/GO TURN ON THE STACKER GATES AS NEEDED
	CLB CMA
	TAD SHLCNT	/COMPUTE THE ADDRESS OF THE NEXT
	TAD (JMPTBL)	/LOCATION IN THE JUMP TABLE, STORE THE
	DCA WKA		/ADDRESS AND GO TO IT
	JMP I WKA
/
/
/	RETURN HERE AFTER EXITING FROM THE JUMP TABLE
/
/
MEMWRT,	CLB
	JMP I MEMWRK

	PAGE