/54
/
/
/%R	PRODUCT DIRECTION ROUTINE
/
/%TW	COME HERE FROM "CHOPCK" FOR EACH CHOP TO DECODE
/	WHICH TRAY THIS SHEET BELONGS IN AND RETURN THE
/	SHEET DESTINATION INFORMATION TO THE DEFECT MEMORY
/	TABLE FOR THE STACKER GATE HANDLER ROUTINES.
/
/%TD	"PRODCT" ALSO CONTROLS CHANGING OF THE ACTIVE TRAYS
/	AS THEY FILL WITH PRODUCT.  DURING A MACHINE CHECK
/	THIS ROUTINE WILL ADD 5 SHEETS TO THE NEXT PRODUCT
/	TRAY (5 SHEETS ARE ADDED TO THE CURRENT PRODUCT TRAY
/	BY "MOPCMD").  IF THE MAINTENANCE FLAG "STAKFG" IS
/	SET, "PRODCT" GOES TO THE STACKER MAINTENANCE DRIVER
/	ROUTINE "STAKCN" FOR THE REQUESTED TRAY DESTINATION,
/	WHICH OVERRIDES THE NORMAL TRAY DIRECTION.  WHEN
/	THE GOOD PRODUCT TRAYS CHANGE, THE "NEWBOX" FLAG IS 
/	SET FOR THE SAMPLE TALLEY ROUTINE "TALGEN" IN FIELD
/	2.
/
/
PRODCT,	0
	CLB
	TAD STAKFG	/IS THE MAINTENANCE FLAG SET ?
	TAD STAKSF
	SNA CLA
	JMP .+3		/NO, GO ON
	JMS STAKCN	/YES, GO TO THE MAINTENANCE ROUTINE
	JMP I PRODCT	/RETURN
	TAD I MEMPTR	/SAVE THE DATA FOR THIS SHEET FOR THE
	DCA SHTDTA	/SAMPLE TALLEY ROUTINE
	TAD I MEMPTR	/IS THIS SHEET MARKED AS A SAMPLE ?
	AND (3160)
	SNA CLA
	JMP PROD1	/NO, GO ON
	TAD SMTFLG	/YES, IS THE SAMPLE TRAY OUT ?
	SNA CLA
	JMP .+4
	TAD (7)		/YES, MARK THE SHEET DATA AS REJECT
	DCA SHTDTA
	JMP PROD1	/GO MARK THIS SHEET AS REJECT
	TAD (0440)	/NO, MARK THE SHEET AS A SAMPLE IN THE
	DCA I MEMPTR	/MEMORY TABLE.
	ISZ SMTCNT	/IS THE SAMPLE TRAY FULL ?
	JMP I PRODCT	/NO, RETURN
	TAD SMTLKF	/YES, IS THE SAMPLE TRAY LOCKED IN ?
	SNA CLA
	JMP .+4		/NO, GO ON
	CLB CMA		/YES, SET THE SAMPLE TRAY SHEET
	DCA SMTLKF	/COUNTER TO -1.
	JMP I PRODCT	/RETURN
/55
	CLB STL RAR	/MARK THE SAMPLE TRAY TO EJECT
	TAD I MEMPTR
	DCA I MEMPTR
	CLB CMA		/SET THE SAMPLE TRAY OUT FLAG
	DCA SMTFLG
	JMP I PRODCT

PROD1,	TAD I MEMPTR	/IS THIS SHEET MARKED AS A REJECT ?
	SNA CLA
	JMP PROD2	/NO, GO SET UP FOR GOOD PRODUCT
	TAD REJFLG	/IS REJECT TRAY A ACTIVE ?
	SNA CLA
	TAD P10		/YES, MARK SHEET FOR REJECT A
	TAD P10		/NO, MARK SHEET FOR REJECT B
	DCA I MEMPTR
	ISZ REJCNT	/IS THE ACTIVE REJECT TRAY FULL ?
	JMP I PRODCT	/NO, RETURN
	CLB STL RAR	/YES, MARK THE REJECT TRAY TO EJECT
	TAD I MEMPTR
	DCA I MEMPTR
	TAD REJFLG	/SET THE OTHER REJECT TRAY TO BE ACTIVE
	CMA
	DCA REJFLG
	TAD TRAYSZ	/RESET THE REJECT TRAY SHEET COUNTER
	DCA REJCNT
	JMP I PRODCT	/RETURN

PROD2,	TAD PROFLG	/IS THE PRODUCT A TRAY ACTIVE ?
	SNA CLA
	IAC		/YES, MARK SHEET FOR PRODUCT A
	IAC		/NO, MARK SHEET FOR PRODUCT B
	DCA I MEMPTR
	ISZ PROCNT	/IS THE ACTIVE PRODUCT TRAY FULL ?
	JMP I PRODCT	/NO, RETURN
	CLB STL RAR	/YES, MARK THE PRODUCT TRAY TO EJECT
	TAD I MEMPTR
	DCA I MEMPTR
	TAD MCKFLG	/IS THE MACHINE CHECK FLAG SET ?
	SZA CLA
	TAD (-5)	/YES, ADD 5 SHEETS TO PRODUCT TRAY
	TAD PUTUP1	/RESET THE PRODUCT TRAY SHEET COUNTER
	DCA PROCNT
	DCA MCKFLG	/CLEAR THE MACHINE CHECK FLAG
	TAD PROFLG	/NO, SET THE OTHER PRODUCT TRAY TO BE
	CMA		/ACTIVE
	DCA PROFLG
	CDF 20
	ISZ I (NEWBOX)	/NEW BOX FLAG FOR THE SAMPLE TALLEY
	CDF 0
	JMP I PRODCT	/RETURN
/56
SMTCNT,	-226		/SAMPLE TRAY SHEET COUNTER
REJFLG,	0		/REJECT TRAY ACTIVE FLAG
REJCNT,	-226		/REJECT TRAY SHEET COUNTER
PROFLG,	0		/PRODUCT TRAY ACTIVE FLAG
PROCNT,	-175		/PRODUCT TRAY SHEET COUNTER
PRCFLG,	0		/PRODUCT TRAY C ACTIVE FLAG
MCKFLG,	0		/MACHINE CHECK FLAG
SHTDTA,	0		/PRODUCT DATA FOR THIS SHEET

	PAGE