Directory of image this file is from
This file as a plain text file

/ SAMPLE TALLEY GENERATOR			22-MAY-90
/
/
/EDIT HISTORY:
/
/26-APR-90	(LHN)
/	1)  DELETED REFERENCES TO RANDOM SAMPLING
/
/22-MAY-90	(LHN)
/	1) CHANGES TO REPORT BOX SAMPLING
/


/
/
/%R	SAMPLE TALLY GENERATOR
/
/%TW	COME HERE AND CHECK EACH CHOP FOR INFORMATION
/	OF INTEREST TO THE SAMPLE TALLY, SUCH AS REJECTS,
/	SAMPLES, SPLICES, AND TALLEY MESSAGES.
/
/	ALL SAMPLE TALLY LINES ORIGINATE HERE !
/	"TALLEY" SHOULD BE HIGHER PRIORITY THAN "CRTCTR".
/
/





	TASK=	TALLEY
	CUR=	TALLYFLD
	INIWT=	0
	VERS=	3






	FIELD TALLYFLD%10

	*TALLYPGZ
TALLA,	0
TALLB,	0

	*TALLYLOC
/
/
/%RT	SHEET TYPE CODE BITS
/
/%TW	THE CODE BITS USED BY MAST FOR MARKING THE TYPE OF
/	SHEET BEFORE THE CHOP LINE ARE AS FOLLOWS:
/
/%TN	DATA		MEANING
/%TN	BIT
/%TN
/%TN	0		TRAY EJECT CONTROL
/%TN	1		SPLICE SAMPLE
/%TN	2		IN-ROLL SPLICE SAMPLE
/%TN
/%TN	3		MANUAL REJECT
/%TN	4		AUTOMATIC REJECT
/%TN	5		BOX SAMPLE
/%TN
/%TN	6		START ROLL SAMPLE
/%TN	7		END ROLL SAMPLE
/%TN	8		SPLICE ON THIS SHEET
/%TN
/%TN	9		DEFECT FROM CHANNEL 1
/%TN	10		DEFECT FROM CHANNEL 2
/%TN	11		DEFECT FROM CHANNEL 3
/%TN
/%TN
/
/
/
/
/
/	THE SHEET CODE BITS AFTER THE CHOP LINE ARE:
/
/
/	DATA		MEANING
/	BIT
/
/	0		EJECT TRAY AFTER THIS SHEET
/	1
/	2
/
/	3		SAMPLE MARK THIS SHEET
/	4
/	5
/
/	6		PUT SHEET IN SAMPLE TRAY
/	7		PUT SHEET IN REJECT A TRAY
/	8		PUT SHEET IN REJECT B TRAY
/
/	9		PUT SHEET IN PRODUCT C TRAY
/	10		PUT SHEET IN PRODUCT A TRAY
/	11		PUT SHEET IN PRODUCT B TRAY
/
/
/
/
/	LETTER CODES FOR THE SAMPLE MARKER
/
/
/	 DATA		  RESULTING
/	NIBBLE		MARKER LETTER
/
/	0		R
/	1		A
/	2		F
/	3		P
/	4		M
/
/	5		K
/	6		D
/	7		T
/	8		C
/	9		N
/
/	10-17		BLANK
/
/
/
START,	CLB
	CAL
	SUSPND		/GO TO SLEEP 'TIL NEEEDED
	CLB
	TAD CHOPFG	/CHOP OCCUR ?
	SNA CLA
	JMP TAL10	/NO, GO ON.
	DCA CHOPFG

	CDF 10
	TAD I (SROFLG)	/ARE WE IN STACKER RUN OUT
	TAD I (CTHOLD)	/OR COUNT/HOLD ?
	SZA CLA
	JMP START	/YES, JUST EXIT.

	ISZ CRTDEF	/SET THE CRT DATA FLAG PENDING,
	TAD (CRTCTR)	/ AND ENABLE THE UPDATER TO RUN.
	CAL
	RUN

	CDF 30
	ISZ I (INCRTC)	/INCREMENT THE CHOP COUNTER FLAG
	CDF 10
	TAD I (MEMPTR)	/GET THE SHEET DESTINATION DATA
	DCA TALLA	/FROM THE DEFECT MEMORY TABLE.
	TAD I TALLA	/
	CDF CUR
	MQL		/SAVE IT IN THE MQ.

	ACL
	AND (0070)	/IS THIS A GOOD PRODUCT SHEET ?
	SZA CLA
	JMP TAL2	/NO, IT IS A REJECT OR SAMPLE.

	TAD NEWBDL	/IS THE BOX CHANGED FLAG SET ?
	SNA CLA
	JMP TAL1	/NO, GO ON

	CDF 30
	AC4000		/RESET THE SHEET COUNTER DISPLAY.
	DCA I (INCRST)
	CLB IAC
	TAD I (SHEARC)	/INCREMENT THE BOX DISPLAY COUNTER
	DCA I (INCRTB)	/BY THE SHEAR CUT.
/
TAL1,	CDF 30
	ISZ I (INCRST)	/INCREMENT THE SHEET/BOX COUNTER
	CDF CUR
	TAD NEWBOX	/DELAY A NEW BOX BY 1 GOOD SHEET.
	DCA NEWBDL
	DCA NEWBOX
	JMP TAL10	/ALL DONE WITH THIS SHEET

TAL2,	ACL
	AND (0047)	/IS THE SHEET A REJECT ?
	SZA CLA
	JMP TAL3	/NO, SHOULD BE A SAMPLE.
	CDF 30
	ISZ I (INCRTR)	/INCREMENT THE REJECT DISPLAY
	CDF CUR
	JMP TAL10	/ALL DONE FOR THIS SHEET.

TAL3,	ACL
	AND (0037)	/IS THIS REALLY A SAMPLE ?
	SZA CLA
	JMP TAL10	/NO, A TRAY MUST BE OUT.

	CDF 30
	ISZ I (INCRTS)	/INCREMENT THE SAMPLE DISPLAY.
	CDF CUR

	CDF 10		/IS THIS IS A BOX SAMPLE ?
	TAD I (CHOPSV)
	CDF CUR
	AND (0100)	/BOX SAMPLE BIT
	SZA CLA
	JMP TAL4	/YES, GO ON
	CDF 30		/NO, INCREMENT SPLICE SAMPLE
	ISZ I (INCRSS)	/ COUNTER.
	CDF CUR

TAL4,	CAL		/NOW WAIT FOR THE CRT UPDATE TO
	WAITE		/ FINISH.
	CRTDEF
	CLB
	JMP TAL5

INFLST,	FORM2A
	FORM2B
	FORM2C
/

	PAGE
/
/	CREATE A SAMPLE TALLEY LINE
/
TAL5,	TAD I TALPTR	/IS THIS BUFFER SLOT PENDING ?
	SNA CLA
	JMP TAL6	/NO, ALL IS OK !
	CAL		/YES, THE PRINTER IS FAILING, GO
	SEND		/ STOP THE MACHINE.
	INLOCK
	TERMG1

	TAD TERMG2	/IS THE CRT MESSAGE PENDING ?
	SZA CLA
	JMP TAL6	/YES, GO ON.
	CAL		/GO DISPLAY THE "PRINTER FAILURE"
	SEND		/ MESSAGE.
	CRTMSG
	TERMG2
	JMP TAL10

TAL6,	TAD TALPTR	/SAVE THE MESSAGE ADDRESS FOR
	DCA TAL8	/ FORMAT.
	TAD TALPTR	/MOVE PAST HEADER AND SET UP THE
	TAD (3)
	DCA XR11

	CDF 10
	TAD I (CHOPSV	/GET THE DETAILS OF THIS SHEET
	MQL		/ LEFT BY PRODCT
	DCA I (CHOPSV)
	CDF CUR

	ACL		/IS THIS A BOX SAMPLE?
	AND (0100)
	SNA CLA
	JMP TAL6A	/NO, GO ON
	TAD (BINBOX-1)	/YES, SET UP DATA ADDRESSES FOR
	DCA XR10	/ BOX SAMPLES.
	TAD (CRTD05+1)
	DCA SAMNAD
	JMP TAL6B

TAL6A,	TAD (BINSSM-1)	/SET UP ADDRESSES FOR SPLICE
	DCA XR10	/ SAMPLES
	TAD (CRTD08+1)
	DCA SAMNAD

TAL6B,	CDF 30
	TAD I (SHEARC)	/GET THE CURRENT SHEAR CUT TO
	CDF CUR		/ DETERMINE WHICH FORMAT TO USE
	TAD (TLFLST)	/FORM THE ADDRESS OF THE FORMAT
	DCA TALLB
	TAD I TALLB
	DCA I XR11
	ISZ XR11	/SKIP OVER INPUT SPEC
/
	TAD I XR10	/MOVE THE SAMPLE NUMBER.
	DCA I XR11

	TAD I XR10
	DCA I XR11
	ISZ XR11	/SKIP OVER THE FORMAT DATA SPEC.

	TAD (BINBOX-1)	/SET UP ADDRESS FOR THE REST OF
	DCA XR10	/ THE DATA FOR THIS TALLEY LINE

	ACL		/IS THIS A SPLICE SAMPLE ?
	AND (2010)
	SNA CLA
	JMP TAL6C
	TAD (4007)	/YES, SAVE THE SPLICE CHARACTER
	DCA SAMTYP	/ (T) FOR THE SAMPLE MARKER.
	ISZ SPLMFG	/SET THE SPLICE MESSAGE FLAG
	JMP TAL9

TAL6C,	ACL
	AND (0040)	/IS THIS A START-ROLL SAMPLE ?
	SNA CLA
	JMP TAL6D
	TAD (4001)	/YES, SAVE THE START-ROLL
	DCA SAMTYP	/ CHARACTER (A) FOR THE SAMPLE
	TAD (4001)	/ MARKER.
	JMP TAL7

TAL6D,	ACL		/IS THIS AN IN-ROLL SPLICE
	AND (1000)	/ SAMPLE ?
	SNA CLA
	JMP TAL6E
	TAD (4010)	/YES, SAVE THE IN-ROLL SPLICE
	DCA SAMTYP	/ CHARACTER (C) FOR THE SAMPLE
	TAD (4003)	/ MARKER
	JMP TAL7

TAL6E,	ACL		/IS THIS AN END-OF-ROLL SAMPLE ?
	AND (0020)	
	SNA CLA
	JMP TAL6F
	TAD (4006)	/YES, SAVE THE END-OF-ROLL 
	DCA SAMTYP	/ CHARACTER (D) FOR THE SAMPLE
	TAD (4004)	/ MARKER
	JMP TAL7

TAL6F,	TAD (4017)	/MUST BE A BOX SAMPLE - SEND A
	DCA SAMTYP	/ BLANK LETTER TO THE MARKER
	TAD (4040)	/JUST 2 SPACES FOR THE TALLEY
	JMP TAL7
/
TLFLST,	FORM1A
	FORM1B
	FORM1C

TERMG1,	ZBLOCK 3	/OPEN MAST MONITOR INTERLOCK
	2000

TERMG2,	ZBLOCK 3	/PRINTER FAILURE CRT MESSAGE
	MOPM10

	PAGE
TAL7,	DCA I XR11	/PUT THE SAMPLE TYPE IN THE MESSAGE

	ISZ XR11	/SKIP OVER INPUT SPEC

	TAD (-7)	/SET UP AND MOVE THE REST OT THE 
	DCA TALLA	/ SAMPLE LINE
	TAD I XR10
	DCA I XR11
	ISZ TALLA
	JMP .-3
	DCA I XR11	/NOW ADD A TERMINATOR

	CDF 30
	TAD I (SHEARC)	/GET THE SHEAR CUT DIGIT
	IAC
	CDF CUR
	JMS NEWLIN	/CHECK IF WE NEED A NEW PAGE

	CAL 		/SEND THE LINE BUFFER TO THE 
	SEND		/ OUTPUT FORMATTER.
	FORMAT
TAL8,	0
	CLB IAC		/UPDATE THE BUFFER SLOT POINTER.
	TAD XR11
	DCA TALPTR

	TAD TALPTR	/ARE WE AT THE END OF THE BUFFER ?
	TAD (-TALEND)
	SPA CLA
	JMP TAL9	/NO, GO ON.
	TAD (TALBUF)
	DCA TALPTR

TAL9,   TAD (SMARKQ)	/RUN THE TADK TO QUEUE
	CAL		/THE SAMPLE MARKER DATA.
	RUN
	JMP TAL10
/
/	CHECK FOR THE END OF A TALLEY PAGE
/

/

NEWLIN, 0
	DCA NEWLA
	CLB
	TAD DWLINE	/IS THE LINE COUNTER = 0 ?
	SNA CLA
	JMP NEWL1	/YES, JUST DO HEADING

	AC3777
	AND NEWLA	/NO, ADD IN THE NUMBER OF LINES
	TAD DWLINE	/ WE NEED.
	SMA
	JMP NEWL1	/NEED A NEW PAGE
	DCA DWLINE	/THIS PAGE IS STILL OK,
	JMP I NEWLIN	/RETURN

NEWL1,	CLB		/SEND OUT A FORM FEED
	CAL		/AND A NEW HEADING.
	SEND
	FORMAT
	NEWMG1

	TAD NEWLB	/
	SNA CLA
	JMP .+3
	CLB IAC
	DCA DWPAGE
	DCA NEWLB

	ISZ DWPAGE	/INCREMENT THE PAGE COUNTER
	TAD NEWLA	/DO WE NEED THE SUB HEADING ?
	SPA CLA
	JMP NEWL2	/NO, GO ON.

	CAL
	SEND
	FORMAT
	NEWMG2

NEWL2,	AC3777		/RESET THE LINE COUNTER
	AND NEWLA
	TAD (-70)
	DCA DWLINE
	JMP I NEWLIN

NEWLA,  0


NEWLB,	0
/
NEWMG1, ZBLOCK 3
	LPTXFLD^100+400+LPT
	FORM10
	0017
	214
	CUR^100+2
	NEWMG4
	CUR^100
	NEWMG5
	LPTXFLD^100
	DWPAGE
	0

NEWMG2, ZBLOCK 3
	LPTXFLD^100+400+LPT
	FORM05
	0

NEWMG4, TEXT "012-345-678-9    "

NEWMG5,	1

	PAGE
/
/
/	CHECK FOR SAMPLE TALLEY MESSAGES
/
/

/
/	MACHINE STOP MESSAGE
/

TAL10,	CLB
	TAD STPMGF	/DID THE MACHINE STOP ?
	SNA CLA
	JMP TAL11	/NO, GO ON.
	DCA STPMGF	/YES, FIRST CLEAR OUR FLAG.

	TAD TAL10M	/IS OUR MESSAGE BUSY ?
	SZA CLA
	JMP TAL11	/YES, FORGET IT.
	CLB IAC
	JMS NEWLIN	/CHECK FOR FULL PAGE
	CAL		/NO, SEND OUT THE STOP MSG
	SEND
	FORMAT
	TAL10M
	JMP TAL11

TAL10M,	ZBLOCK 3
	LPTXFLD^100+400+LPT
	FORM24
	CUR^100
	BINCHP
	0
/
/	MACHINE CHECK MESSAGE
/

TAL11,	CLB
	TAD MCKMGF	/MACHINE CHECK FLAG SET ?
	SNA CLA
	JMP TAL12	/NO, GO ON.
	TAD TAL11M	/IS OUR MESSAGE BUSY ?
	SZA CLA
	JMP TAL12	/YES, GO ON.

	TAD MCKMGF	/GET THE DATA IN OUR FLAG
	BSW
	AND (0007)
	TAD (300)
	DCA TAL11A	/SAVE THE TRAY LETTER.
	TAD MCKMGF
	AND (0007)
	TAD (260)
	DCA TAL11B	/SAVE THE SHEET COUNT
	DCA MCKMGF	/CLEAR OUR FLAG.
	CLB IAC
	JMS NEWLIN	/CHECK FOR FULL PAGE

	CAL		/LOG OUR MESSAGE
	SEND
	FORMAT
	TAL11M
	JMP TAL12


TAL11M,	ZBLOCK 3
	LPTXFLD^100+400+LPT
	FORM23
	0016
TAL11A,	301		/TRAY LETTER
	0016
TAL11B,	265		/SHEET COUNT
	0
/
/	EMULSION MISS MESSAGE
/

TAL12,	CLB
	TAD EMFMGF	/EMULSION MISS FLAG SET ?
	SNA CLA
	JMP TAL13	/NO, GO ON.

	TAD EMFMGD	/WAS IT SET THE LAST TIME.
	SZA CLA		/THRU.
	JMP TAL14	/YES, GO ON.

	TAD TAL12M	/IS OUR MESSAGE BUSY ?
	SZA CLA
	JMP TAL14

	TAD BINCHP	/MOVE THE CHOP COUNTER
	DCA TAL12A
	TAD BINCHP+1
	DCA TAL12A+1
	CLB IAC
	JMS NEWLIN	/CHECK FOR FULL PAGE
	CAL
	SEND
	FORMAT
	TAL12M

	ISZ EMFMGD	/SET THE EM MESSAGE ACTIVE FLAG.
	JMP TAL14

TAL12M,	ZBLOCK 3
	LPTXFLD^100+400+LPT
	FORM25
	0010
TAL12A,	0
	0
	0

TAL13,	TAD EMFMGD	/WAS IT SET THE LAST TIME THRU ?
	SNA CLA
	JMP TAL14	/NO, GO ON.

	TAD TAL13M	/IS OUR MESSAGE BUSY ?
	SZA CLA
	JMP TAL14	/YES, GO ON ?

	DCA EMFMGD	/CLEAR THE EM MESSAGE ACTIVE FLAG.
	TAD BINCHP	/MOVE THE CHOP COUNTER
	DCA TAL13A
	TAD BINCHP+1
	DCA TAL13A+1

	CLB IAC
	JMS NEWLIN	/CHECK FOR FULL PAGE
	CAL		/GO LOG OUR MESSAGE
	SEND
	FORMAT
	TAL13M
	JMP TAL14
/
TAL13M,	ZBLOCK 3
	LPTXFLD^100+400+LPT
	FORM26
	0010
TAL13A,	0
	0
	0

	PAGE
/
/	PUTUP CHANGE MESSAGE
/
TAL14,	CLB
	TAD NPCODE	/NEW PUT UP CODE ?
	SNA CLA
	JMP TAL15	/NO, GO ON.

	TAD TAL14M	/IS OUR MESSAGE BUSY ?
	SZA CLA
	JMP TAL15
	DCA NPCODE	/CLEAR OUR FLAG.
	CLB IAC
	JMS NEWLIN	/CHECK FOR FULL PAGE
	CAL
	SEND
	FORMAT
	TAL14M

	JMP TAL15


TAL14M,	ZBLOCK 3
	LPTXFLD^100+400+LPT
	FORM22
	CRTXDF^100+2
	CRTX07
	CUR^100
	BINBOX
	0

/
/	NEW SAMPLING CODE MESSAGE
/

TAL15,	CLB
	TAD NSCODE	/NEW SAMPLING CODE ?
	SNA CLA
	JMP TAL16	/NO, GO ON.

	TAD TAL15M	/IS OUR MESSAGE BUSY ?
	SZA CLA
	JMP TAL16	/YES, GO ON
	DCA NSCODE	/CLEAR OUR FLAG

	TAD BINCHP	/MOVE THE CHOP COUNTER
	DCA TAL15A
	TAD BINCHP+1
	DCA TAL15A+1

	CLB IAC
	JMS NEWLIN	/CHECK FOR FULL PAGE
	CAL
	SEND
	FORMAT
	TAL15M
	JMP TAL16

TAL15M,	ZBLOCK 3
	LPTXFLD^100+400+LPT
	FORM21
	CRTXDF^100+2
	CRTX08
	0010
TAL15A,	0
	0
	0
/
/
/	SPLICE MESSAGE
/
/
TAL16,	0
	TAD SPLMFG	/SPLICE MESSAGE FLAG SET
	SNA CLA
	JMP TAL17

	TAD TAL16M	/SPLICE MESSAGE FLAG SET
	SZA CLA
	JMP TAL17
	DCA SPLMFG	/CLEAR OUR LAG

	TAD BINCHP	/MOVE THE CHOP COUNT
	DCA TAL16A
	TAD BINCHP+1
	DCA TAL16A+1

	CLB IAC
	JMS NEWLIN	/CHECK FOR FULL PAGE
	CAL
	SEND		/SEND OUT THE MESSAGE
	FORMAT
	TAL16M
	JMP TAL17


TAL16M,	ZBLOCK 3
	LPTXFLD^100+400+LPT
	FORM20
	0010
TAL16A,	0
	0
	0



TAL17,
TAL18,
TAL19,
/
/
/	LOOK FOR END OF ROLL WORK TO DO
/
/
/
TAL20,	CLB
	TAD EORSFG	/END OF ROLL SEQUENCE FLAG SET ?
	SZA CLA
	JMP TALEOR	/YES, TO DO IT

TAL21,	CLB
	TAD CLRTOT	/SHOULD WE TRY TO CLEAR TOTALS ?
	SNA CLA
	JMP TAL22

	TAD TEM7	/ARE THE TOTALS PRINTED ?
	SZA CLA
	JMP TAL22

	DCA CLRTOT	/CLEAR OUR FLAG
	TAD (-13)	/YES, DO IT 
	DCA TALLA
	TAD (TEM6A-1)
	DCA XR10
	DCA I XR10
	ISZ TALLA
	JMP .-2

TAL22,	TAD NXTRID	/NEXT ROLL ID
	SNA CLA
	JMP TAL23
	TAD TEM9
	SZA CLA
	JMP TAL23
	DCA NXTRID
	ISZ MROLLF
	JMP TAL23


	PAGE
/
TAL23,  CLB
	TAD MROLLF	/SHOULD WE MOVE THE ROLL NUMBER ?
	SNA CLA
	JMP TAL24

	DCA MROLLF 		/CLEAR OUR FLAG
	TAD (-10)	/MOVE THE ROLL NUMBER LOCALLY
	DCA TALLA
	TAD (NEWMG4-1)
	DCA XR10
	TAD (CRTX06-1)
	DCA XR11

	CDF 30
	TAD I XR11
	CDF CUR
	DCA I XR10
	ISZ TALLA
	JMP .-5

	TAD BINSHR	/UPDATE THE SHIFT ROLL NUMBER.
	DCA NEWMG5
TAL24,	JMP START
/
/
/	DO END OF ROLL SUMMARY
/
/

TALEOR,	CLB		/LOCK OUT THE CRT DATA UPDATER.
/	TAD (CRTCTR)
/	CAL
/	BLKARG
/	USERWT

	CLB		/CHECK FOR NEW SHIFT.
	CDF 30
	TAD I (SHFTRL)
	SZA CLA
	AC4000
	IAC		/YES, SAY RESET BEFORE
	DCA I (INCRSR)	/ INCREMENTING SHIFT ROLL
	DCA I (SHFTRL)	/CLEAR OUR FLAG
/	CDF CUR
/	DCA RANCTR	/CLEAR THE RANDOM SAMPLE
/	CLB CMA		/COUNTER TO FORCE NEW NUMBERS
/	DCA RAN500	/IF IT IS IN USE.
/	CDF 30
	TAD I (SISRLF)	/IS THIS A SISTER ROLL OR
	CDF CUR
	TAD SISSEQ	/ARE WE IN A SISTER SEQUENCE ?
	SNA CLA
	JMP TALE2	/NO, TO ON.
/
/	DO SISTER ROLL SUBTOTALS
/
	CDF 30
	TAD I (SISRLF)	/UPDAFTE THE SISTER SEQUENCE FLAG

	DCA SISSEQ
	CDF CUR

	TAD (4012)	/WILL THE TOTALS FIT ON THIS PAGE ?
	JMS NEWLIN
	TAD NEWMG4+6	/MOVE THE SISTER ROLL CUT NUMBER.
	BSW
	DCA TEM1A
	TAD BINSHR	/MOVE THE SHIFT ROLL NUMBER.
	DCA TEM1B
/
	CAL		/SEND OUT OUR HEADER
	SEND 
	FORMAT
	TEM1

	CAL
	SEND
	FORMAT
	TEM2

	CLB
	TAD (TEM3A-1)	/NOW MOVE THE SISTER ROLL
	DCA XR11	/SUBTOTALS.
	JMS TALMA

	CAL		/SEND OUT OUR SUBTOTAL LINE
	SEND
	FORMAT
	TEM3
	CLB
	TAD (TEM3A-1)
	DCA XR10	/SET UP TO ADD DATA
	TAD (TEM6A)	/INTO TOTAL AREA.
	DCA TALLB
	TAD I XR10	/MOVE THE BOX & SHEET
	DCA I TALLB	/COUNT IN CASE THIS IS
	ISZ TALLB	/THE LAST SISTER.
	TAD I XR10
	DCA I TALLB
	ISZ TALLB
	TAD I XR10
	DCA I TALLB
	ISZ TALLB

	TAD (-4)
	DCA TALLA
TALE1,	CLB

	TAD I XR10		/ADD THE LOW ORDER DATA
	TAD I TALLB
	DCA I TALLB
	ISZ TALLB
	RAL
	TAD I XR10		/AND THE HIGH ORDER DATA.
	TAD I TALLB
	DCA I TALLB
	ISZ TALLB
	ISZ TALLA
	JMP TALE1

	CDF 30
	TAD I (SISRLF)		/NEXT ROLL A SISTER ?
	CDF CUR
	SNA CLA
	JMP TALE3		/NO, OUTPUT GRAND TOTALS

	CDF 30
	DCA I (SISRLF)		/CLEAR OUR FLAG
	CDF CUR
	CAL			/YES, OUT WITH OUR HEADING.
	SEND
	FORMAT
	TEM4
	JMP TALE4

/
	PAGE
/
/
/	DO GRAND TOTALS
/
/
TALE2,	CLB
	ISZ CLRTOT	/SET THE CLEAR TOTALS FLAG
	TAD (TEM6A-1)	/MOVE DATA TO THE TOTAL AREA
	DCA XR11
	JMS TALMA

TALE3,	TAD (4012)
	JMS NEWLIN

	CAL		/FIRST OUR HEADING
	SEND
	FORMAT
	TEM5

	CAL
	SEND
	FORMAT
	TEM2

	CAL		/THEN OUR TOTALS
	SEND
	FORMAT
	TEM6

	CAL		/NOW START A NEW PAGE
	SEND
	FORMAT
	TEM7

	CLB
	TAD (-70+10)	/RESET THE LINES PER PAGE COUNTER
	DCA DWLINE

	CAL
	SEND
	FORMAT
	TEM8

	CDF 30		/NOW CLEAR THE CRT COUNTERS
	AC4000
	IAC
	TAD I (INCRTB)
	DCA I (INCRTB)
	AC4000
	TAD I (INCRST)
	DCA I (INCRST)
	CDF CUR

	CLB IAC
	DCA NEWLB	/SET THE PAGE # RESET FLAG
/
TALE4,	CDF 30		/NOW WE RESET THE CRT COUNTERS
	AC4000
	TAD I (INCRTC)
	DCA I (INCRTC)
	AC4000
	TAD I (INCRTR)
	DCA I (INCRTR)
	AC4000
	TAD I (INCRTS)
	DCA I (INCRTS)
	AC4000
	TAD I (INCRTM)
	DCA I (INCRTM)
	AC4000
	TAD I (INCRSS)
	DCA I (INCRSS)

	DCA EORSFG	/CLEAR THE END OF ROLL FLAG
	ISZ NXTRID	/ROLL ID UPDATE FLAG

	CAL		/SEND OUT TALLEY DATA HEADER.
	SEND
	FORMAT
	TEM9

	TAD (ENDROL)
	CAL
	RUN

	JMP TAL21
/
/	MOVE PRODUCT DATA FOR OUTPUT
/

TALMA,	0
	CLB
	TAD (BINBOX-1)
	DCA XR10
	TAD (-7)		/MOVE,BOX,SHEETS,CHOPS AND
	DCA TALLA		/REJECTS
	TAD I XR10
	DCA I XR11
	ISZ TALLA
	JMP .-3

	TAD BINSAM		/NOW THE SAMPLES.
	DCA I XR11
	TAD BINSAM+1
	DCA I XR11
	
	TAD I XR10		/LASTLY THE METER.
	DCA I XR11
	TAD I XR10
	DCA I XR11
	JMP I TALMA


	PAGE
/
/
/	SISTER ROLL HEADERS
/
TEM1,	ZBLOCK 3
	LPTXFLD^100+400+LPT
	FORM06
	0012
TEM1A,	0
	0010
TEM1B,	0
	0

TEM2,	ZBLOCK 3
	LPTXFLD^100+400+LPT
	FORM07
	0

TEM3,	ZBLOCK 3
	LPTXFLD^100+400+LPT
	FORM09
	0110
TEM3A,	0		/BOX COUNT
	0
	0		/SHEET IN BOX
TEM3B,	0		/CHOPS
	0
	0		/REJECTS
	0
	0		/SAMPLES
	0
	0		/METERS
	0
	0

TEM4,	ZBLOCK 3
	LPTXFLD^100+400+LPT
	FORM28
	CRTXDF^100+2
	CRTX06
	CUR^100
	BINSHR
	0
/
/	GRAND TOTAL HEADINGS
/
TEM5,	ZBLOCK 3
	LPTXFLD^100+400+LPT
	FORM08
	CUR^100+2
	NEWMG4
	0

TEM6,	ZBLOCK 3
	LPTXFLD^100+400+LPT
	FORM09
	0110
TEM6A,	0		/BOX COUNT
	0
	0		/SHEET IN BOX
TEM6B,	0		/CHOPS
	0
	0		/REJECTS
	0
	0		/SAMPLES
	0
	0		/METERS
	0
	0

TEM7,	ZBLOCK 3
	LPTXFLD^100+400+LPT
	FORM03
	0017		/FORM FEED
	0214
	CRTXDF^100+2
	CRTX06
	CUR^100
	BINSHR
	0

TEM8,	ZBLOCK 3
	LPTXFLD^100+400+LPT
	FORM04
	CRTXDF^100+2
	CRTX07
	CRTXDF^100+2
	CRTH01+3
	CRTXDF^100+2
	CRTX08
	CRTXDF^100+2
	CRTH02+4
	CRTXDF^100+2
	CRTX09
	CRTXDF^100+2
	CRTX10
	CRTXDF^100+2
	CRTH03+5
	0
/
TEM9,	ZBLOCK 3
	LPTXFLD^100+400+LPT
	FORM05
	0


	PAGE

	NOPUNCH
	XLIST 1